Lösung Beispiel 5, Helmut Hörner Mat.Nr. 08850092

Definiere Potentialwall (drei Bereiche 0, v0, 0)

pot={0,v0,0};

Schrödingergleichung für die drei Bereiche i = 1...3

schrgl=Table[-((ℏ^2)/(2m)) ψ[i]''[x]+pot[[i]] ψ[i][x]==ekin ψ[i][x],{i,1,3}]

Allgemeine Lösung der Schrödingergleichung in drei Bereichen  i = 1...3

rules1={m>0, ekin>0, ℏ>0, v0>0, ekin<v0};
substEnergy={(( (Sqrt[2(v0 m-ekin m)]))/ℏ)->α, ((Sqrt[2 ekin m])/ℏ)->k};
substAlphaK={α-> (( (Sqrt[2(v0 m-ekin m)]))/ℏ), k-> ((Sqrt[2 ekin m])/ℏ)};
lsgAllg = Table[DSolve[schrgl[[i]],ψ[i][x],x,Assumptions->rules1],{i,1,3}]  /.substEnergy // Flatten

Ersetzen der wiederkehrenden Parameter C[1] und C[2] durch individuelle Parameter

parameter={{a1,b1},{a2,b2},{a3,b3}};
lsg2=Table[lsgAllg[[i]] /. {C[1]-> parameter[[i,1]],C[2]-> parameter[[i,2]]},{i,1,3}]

Darstellung in der Form (e^(i k x))

lsg3 = Collect[TrigToExp[lsg2],E^_] /.{((a_)/2)-((I b_)/2)->a,((a_)/2)+((I b_)/2)->b}

Ann: Welle läuft von links nach rechts -> keine Reflexion im Bereich 3

lsg4=lsg3 /. b3->0

Anschlussbedingungen

stetigkeit = {(lsg4[[1,2]]/. x->0 )==(lsg4[[2,2]]/. x->0 ),(lsg4[[2,2]]/. x->x1 )==(lsg4[[3,2]]/. x->x1 )};
stetigkeitAbl = {(D[lsg4[[1,2]],x]/. x->0 )==(D[lsg4[[2,2]],x]/. x->0 ),(D[lsg4[[2,2]],x]/. x->x1 )==(D[lsg4[[3,2]],x]/. x->x1 )};
anschlussbed=Join[stetigkeit,stetigkeitAbl]

Berechnung der Parameter aus den Anschlussbedingungen

parameterSol = FullSimplify[Solve[anschlussbed,{b1, a2, b2, a3}]] // Flatten

Fertige Wellenfunktion für alle drei Bereiche

regeln={Im[m]==0, Im[k]==0,Im[α]==0, Im[x1]==0, Im[ℏ]==0, Im[v0]==0, Im[ekin]==0,ekin<v0, m>0, ℏ>0, ekin>0, v0>0};
lsgFinal = FullSimplify[lsg4 /. parameterSol,Assumptions->regeln]
psiPiecewiese[x_,A_,x1_]=Piecewise[{{lsgFinal[[1,2]],x<0},{lsgFinal[[3,2]],x>x1}},lsgFinal[[2,2]]] /.{a1->A}

Transmissionskoeffizient (einmal abh. von k und α; und einmal abh. von v0, ekin und x1)

T1=((ComplexExpand[FullSimplify[Abs[(a3/a1)/.parameterSol],Assumptions->regeln]])^2)
T2=FullSimplify[FullSimplify[T1/. ((Cosh[u_])^2)-> 1+((Sinh[u])^2)]/.substAlphaK ,Assumptions->regeln]

Reflexionskoeffizient  (einmal abh. von k und α; und einmal abh. von v0, ekin und x1)

R1=((ComplexExpand[FullSimplify[Abs[(b1/a1)/.parameterSol],Assumptions->regeln]])^2)
R2=Together[FullSimplify[R1 /.substAlphaK ,Assumptions->regeln]]

Probe: R+T=1

FullSimplify[{R1+T1,R2+T2}]

MANIPULATE: Realteil der Wellenfunktion über alle drei Bereiche

physconst={ℏ-> 6.62606896 (10^(-34)),m-> 9.10938215 (10^(-31)), echrg-> 1.60217649 (10^(-19))};
Manipulate[Show[Plot[Re[psiPiecewiese[xx,1 /2,x1] /. substAlphaK /. {ekin-> Min[EKIN,V0] echrg, v0-> V0 echrg} /. physconst],{xx,-6 (10^(-9)),6 (10^(-9))},PlotRange->{-1,1}],Graphics[{Thick,Red,Line[{{0,-2},{0,2}}],Line[{{x1,-2},{x1,2}}]}]],{{V0,11},0.02,11},{{EKIN,10},0,11-0.01},{{x1,2 (10^(-9))},0 (10^(-9)),3 (10^(-9))}]

MANIPULATE: Aufenthaltswahrscheinlichkeit über alle drei Bereiche

Manipulate[Show[Plot[((Abs[psiPiecewiese[xx,1 /2,x1] /. substAlphaK /. {ekin-> Min[EKIN,V0] echrg, v0-> V0 echrg} /. physconst])^2),{xx,-6 (10^(-9)),6 (10^(-9))},PlotRange->{0,1}],Graphics[{Thick,Red,Line[{{0,-2},{0,2}}],Line[{{x1,-2},{x1,2}}]}]],{{V0,11},0.02,11},{{EKIN,10},0,11-0.01},{{x1,0.5 (10^(-9))},0 (10^(-9)),3 (10^(-9))}]